Bugfix: ls與format

我已經修正完畢LS函數和FORMAT函數的Bug，下面列出的是FORMAT的定義。至於LS的定義修改方式很簡單，把LENGTH?用LENGTH+?取代即可。當FORMAT遇到中文時，終於不會出問題了！

LENGTH+?不會計算出字串的字元長度，而是會計算出「相當於多少個half-width字元」的長度。記得把前一篇文章的Full-Wide-Width-charset定義也加進來，因為LENGTH+?會用到這個定義。

我會找一天把修正後的結果透過DevBase遞交給REBOL公司。

length+?: func [str [string!] /local ans ] [
    ans: 0
    foreach ch str [
        either find Full-Wide-Width-charset ch [
           ans: ans + 2
        ] [
           ans: ans + 1
        ]
    ]
]

format: make function! [[
    "Format a string according to the format dialect."
    rules {A block in the format dialect. E.g. [10 -10 #"-" 4]}
    values
    /pad p
    /local out val
][
    p: any [p #" "]
    unless block? :rules [rules: reduce [:rules]]
    unless block? :values [values: reduce [:values]]
    out: make string! ""
    foreach rule rules [
        if word? :rule [rule: get rule]
        switch type?/word :rule [
            integer! [
                val: first+ values
                val: form :val
                pad: (abs rule) - length+? val
                if negative? pad [ pad: 0 ]
                either positive? rule [
                    append out :val
                    append/dup out p pad
                ] [
                    append/dup out p pad
                    append out :val
                ]
            ]
            string! [append out rule]
            char! [append out rule]
        ]
    ]
    if not tail? values [append out values]
    head out
]]